Configure Code Generation

9min
Overview
At this point the Terraform modules have been connected, the module variables have been defined, the module dependencies have been connected, and the user experience has been defined. It is now time to add the blueprint resource, define the files to be generated, and configure the git destination for the generated code to be submitted.
Add Blueprint Resource
The autocloud_blueprint resource ties all the assets together to create the consumer user experience. The first step is to define the resource and the metadata associated with the Terraform blueprint. Add the resource block below to the end of main.tf:
Terraform
####
# Create Blueprint
#
# Create generator blueprint that contains all the elements
resource "autocloud_blueprint" "this" {
  name = "KMS Encrypted S3 Bucket"

  ###
  # UI Configuration
  #
  author       = "jim@unstyl.com"
  description  = "Deploys a KMS Encrypted S3 Bucket to AWS"
  instructions = <<-EOT
  To deploy this generator, these simple steps:

    * step 1: Choose the target environment
    * step 2: Provide a name to identify assets
    * step 3: Add tags to apply to assets
  EOT

  labels = ["aws"]

  ###
  # Form configuration
  config = data.autocloud_blueprint_config.global.config
}
####
# Create Blueprint
#
# Create generator blueprint that contains all the elements
resource "autocloud_blueprint" "this" {
  name = "KMS Encrypted S3 Bucket"

  ###
  # UI Configuration
  #
  author       = "jim@unstyl.com"
  description  = "Deploys a KMS Encrypted S3 Bucket to AWS"
  instructions = <<-EOT
  To deploy this generator, these simple steps:

    * step 1: Choose the target environment
    * step 2: Provide a name to identify assets
    * step 3: Add tags to apply to assets
  EOT

  labels = ["aws"]

  ###
  # Form configuration
  config = data.autocloud_blueprint_config.global.config
}
﻿
This resource now has a short display name (name) to identify the pattern in the catalog, along with the blueprint author, helper text describing what the blueprint does, and instructions to show the consumer when they deploy the pattern. The instructions block supports plain text as well as standard markdown. A set of labels are given to filter by, in this case identifying the cloud provider this blueprint targets.
Finally, the blueprint configuration defined in the previous steps is passed to the blueprint to define the user experience.
With all the contents and user experience defined, the generated code needs to be sent somewhere.
Define Files to Generate
The AutoCloud Terraform blueprint generates code, and that code must live in files somewhere. The filenames are defined using file blocks. Add the following block to the autocloud_blueprint resource:
Terraform
###
# File definitions
#
file {
  action      = "CREATE"
  destination = "aws/{{environment}}/{{namespace}}-{{environment}}-{{name}}.tf"
  variables = {
    namespace   = "cpkmskey.namespace"
    environment = "cpkmskey.environment"
    name        = "cpkmskey.name"
  }

  modules = [
    autocloud_module.kms_key.name,
    autocloud_module.s3_bucket.name,
  ]
}
###
# File definitions
#
file {
  action      = "CREATE"
  destination = "aws/{{environment}}/{{namespace}}-{{environment}}-{{name}}.tf"
  variables = {
    namespace   = "cpkmskey.namespace"
    environment = "cpkmskey.environment"
    name        = "cpkmskey.name"
  }

  modules = [
    autocloud_module.kms_key.name,
    autocloud_module.s3_bucket.name,
  ]
}
﻿
The file definition block consists of four elements. The action should currently always be CREATE, though future actions may be defined.
The destination argument defines the full file path and name relative to the git repository root for the file being generated. This filename may be dynamically populated using template interpolation. Similar to Jinja template syntax, a string variable stringvar may be defined in the variables block, whose value is substituted in the filename using the slug {{stringvar}}. The variables may reference module variable values using dot notation. Note that the module is referenced by the name attribute of the autocloud_module resource (cpkmskey), and not Terraform resource name (kms_key). In this example, our code is organized by environment, and all assets generated by this blueprint will be stored in a single file that corresponds to the full name of the resources generated.
The modules argument is a list of the generated module blocks to put in the file. Note that the modules are referenced by the Terraform resource name of the autocloud_module resource (kms_key), and not the name attribute (cpkmskey).
As many file blocks as desired can be added to accommodate your organization's Terraform code repository structure.
Configure Git Repository Submission
Now that the blueprint is defined and the files for the generated code are configured, the git submission behavior must be set. A pull request must be generated and sent to a destination git repository to be reviewed and deployed.
Chose Connected Git Repository
Filter the git repositories connected to AutoCloud to give the consumer the choice of destination for their generated code. Add a local variable to main.tf to filter the repositories based on URL:
Terraform
data "autocloud_github_repos" "repos" {}

####
# Local variables
locals {
  # Destination repos where generated code will be submitted
  dest_repos = [
    for repo in data.autocloud_github_repos.repos.data[*].url : repo
    if length(regexall("/infrastructure-live-demo", repo)) > 0
  ]
}
data "autocloud_github_repos" "repos" {}

####
# Local variables
locals {
  # Destination repos where generated code will be submitted
  dest_repos = [
    for repo in data.autocloud_github_repos.repos.data[*].url : repo
    if length(regexall("/infrastructure-live-demo", repo)) > 0
  ]
}
﻿
Add Pull Request Template
The content for the pull request submitted to git is provided to the autocloud_blueprint resource as a string, and any suitable source may be used. For this example, the content will be sourced from a file stored with the Terraform source code. Create a directory to store template files and add an empty pull request template:
Shell
❯ mkdir -p files

❯ touch files/pull_request.md.tpl

❯ ls -1 files
pull_request.md.tpl
❯ mkdir -p files

❯ touch files/pull_request.md.tpl

❯ ls -1 files
pull_request.md.tpl
﻿
Add the pull request template content to this file:
Markdown
# New request for KMS Encrypted S3 Bucket
#### _🚀 Generated with AutoCloud_

#### Changes included in this Pull Request

**Note:** You are seeing this because you or someone else with access to this repository has authorized AutoCloud to open PRs.

🛠  To change the current settings, please get in touch with us

# New request for KMS Encrypted S3 Bucket
#### _🚀 Generated with AutoCloud_

#### Changes included in this Pull Request

**Note:** You are seeing this because you or someone else with access to this repository has authorized AutoCloud to open PRs.

🛠  To change the current settings, please get in touch with us
﻿
Define Git Destination
Now that the destination repository and the pull request content are configured, define the git destination in the autocloud_blueprint resource. Add the following block to the resource definition:
Terraform
  ###
  # Destination repository git configuraiton
  #
  git_config {
    destination_branch = "main"

    git_url_options = local.dest_repos
    git_url_default = length(local.dest_repos) != 0 ? local.dest_repos[0] : "" # Choose the first in the list by default

    pull_request {
      title                   = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      commit_message_template = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      body                    = file("./files/pull_request.md.tpl")
      variables = {
        authorName = "generic.authorName"
        namespace   = "cpkmskey.namespace"
        environment = "cpkmskey.environment"
        name        = "cpkmskey.name"
      }
    }
  }
  ###
  # Destination repository git configuraiton
  #
  git_config {
    destination_branch = "main"

    git_url_options = local.dest_repos
    git_url_default = length(local.dest_repos) != 0 ? local.dest_repos[0] : "" # Choose the first in the list by default

    pull_request {
      title                   = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      commit_message_template = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      body                    = file("./files/pull_request.md.tpl")
      variables = {
        authorName = "generic.authorName"
        namespace   = "cpkmskey.namespace"
        environment = "cpkmskey.environment"
        name        = "cpkmskey.name"
      }
    }
  }
﻿
The configuration options should be intuitive for those familiar with git. All strings in the pull_request block may be dynamically populated with template interpolation. Similar to Jinja template syntax, a string variable stringvar may be defined in the variables block, whose value is substituted in pull request elements using the slug {{stringvar}}. The variables may reference module variable values using dot notation. Note that the module is referenced by the name attribute of the autocloud_module resource (cpkmskey), and not Terraform resource name (kms_key).
Review
The AutoCloud blueprint code generation configuration is now complete. The autocloud_blueprint resource should look like this:
Terraform
####
# Create Blueprint
#
# Create generator blueprint that contains all the elements
resource "autocloud_blueprint" "this" {
  name = "KMS Encrypted S3 Bucket"

  ###
  # UI Configuration
  #
  author       = "jim@unstyl.com"
  description  = "Deploys a KMS Encrypted S3 Bucket to AWS"
  instructions = <<-EOT
  To deploy this generator, follow these simple steps:

    * step 1: step-1-description
    * step 2: step-2-description
    * step 3: step-3-description
  EOT

  labels = ["aws"]



  ###
  # Form configuration
  config = data.autocloud_blueprint_config.global.config



  ###
  # File definitions
  #
  file {
    action      = "CREATE"
    destination = "aws/{{environment}}/{{namespace}}-{{environment}}-{{name}}.tf"
    variables = {
        namespace   = "cpkmskey.namespace"
        environment = "cpkmskey.environment"
        name        = "cpkmskey.name"
    }

    modules = [
      autocloud_module.kms_key.name,
      autocloud_module.s3_bucket.name,
    ]
  }



  ###
  # Destination repository git configuraiton
  #
  git_config {
    destination_branch = "main"

    git_url_options = local.dest_repos
    git_url_default = length(local.dest_repos) != 0 ? local.dest_repos[0] : "" # Choose the first in the list by default

    pull_request {
      title                   = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      commit_message_template = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      body                    = file("./files/pull_request.md.tpl")
      variables = {
        authorName = "generic.authorName"
        namespace   = "cpkmskey.namespace"
        environment = "cpkmskey.environment"
        name        = "cpkmskey.name"
      }
    }
  }
}
####
# Create Blueprint
#
# Create generator blueprint that contains all the elements
resource "autocloud_blueprint" "this" {
  name = "KMS Encrypted S3 Bucket"

  ###
  # UI Configuration
  #
  author       = "jim@unstyl.com"
  description  = "Deploys a KMS Encrypted S3 Bucket to AWS"
  instructions = <<-EOT
  To deploy this generator, follow these simple steps:

    * step 1: step-1-description
    * step 2: step-2-description
    * step 3: step-3-description
  EOT

  labels = ["aws"]



  ###
  # Form configuration
  config = data.autocloud_blueprint_config.global.config



  ###
  # File definitions
  #
  file {
    action      = "CREATE"
    destination = "aws/{{environment}}/{{namespace}}-{{environment}}-{{name}}.tf"
    variables = {
        namespace   = "cpkmskey.namespace"
        environment = "cpkmskey.environment"
        name        = "cpkmskey.name"
    }

    modules = [
      autocloud_module.kms_key.name,
      autocloud_module.s3_bucket.name,
    ]
  }



  ###
  # Destination repository git configuraiton
  #
  git_config {
    destination_branch = "main"

    git_url_options = local.dest_repos
    git_url_default = length(local.dest_repos) != 0 ? local.dest_repos[0] : "" # Choose the first in the list by default

    pull_request {
      title                   = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      commit_message_template = "[AutoCloud] new KMS Encrypted S3 Bucket {{namespace}}-{{environment}}-{{name}}, created by {{authorName}}"
      body                    = file("./files/pull_request.md.tpl")
      variables = {
        authorName = "generic.authorName"
        namespace   = "cpkmskey.namespace"
        environment = "cpkmskey.environment"
        name        = "cpkmskey.name"
      }
    }
  }
}
﻿
﻿
Updated 01 Jun 2023
Did this page help you?
Configure Variables
Create Blueprint
Docs powered by Archbee
TABLE OF CONTENTS
Overview
Add Blueprint Resource
Define Files to Generate
Configure Git Repository Submission
Chose Connected Git Repository
Add Pull Request Template
Define Git Destination
Review